Integrals from lecture 22 (Van der Walls potential).

ClearAll[x,y,z, theta, phi, braketSpherical,braketSurface, display, psi,sopts,a0, psi2s, psi2px, psi2py, psi2pz, row, b,v, e, electricField ]

$Assumptions=(And@@(#>0&)/@{a0, e, electricField});

x = Sin[theta] Cos[phi] ;
y = Sin[theta] Sin[phi] ;
z = Cos[theta] ;

braketSurface[f_, g_] := Integrate[ Sin[theta] Conjugate[f] g, {theta, 0, Pi}, {phi, 0, 2 Pi} ] ;

braketSpherical[f_,g_] := Integrate[r^2 braketSurface[f,g], {r, 0, Infinity}] ;



(*http://mathematica.stackexchange.com/a/88150/10*)
psi[{n_,l_,m_},{r_,θ_,ϕ_}]:=With[{ρ=2 r/(n a0)},Sqrt[(2/(n a0))^3 (n-l-1)!/(2 n (n+l)!)] Exp[-ρ/2] ρ^l LaguerreL[n-l-1,2 l+1,ρ] SphericalHarmonicY[l,m,θ,ϕ]] ;

psi2s[r_, theta_, phi_] = psi[{2,0,0},{r,theta, phi}] ;
psi2px[r_, theta_, phi_] = -(psi[{2,1,1},{r,theta, phi}] - psi[{2,1,-1},{r,theta, phi}])/Sqrt[2] // Simplify ;
psi2py[r_, theta_, phi_] = I(psi[{2,1,1},{r,theta, phi}] + psi[{2,1,-1},{r,theta, phi}])/Sqrt[2] ;
psi2pz[r_, theta_, phi_] = psi[{2,1,0},{r,theta, phi}] ;

b = {psi2s, psi2px, psi2py, psi2pz} ;
row[n_] := braketSpherical[b[[n]][r,theta,phi], r Cos[theta] b[[#]][r, theta,phi]] &/@ Range[4] ;
v = e electricField(row[#] &/@ Range[4] ) ;


ei = Eigensystem[ v ] ;

sopts = {14, "Text"} ;
display = {a0 -> "(Subscript[a, 0])", electricField -> "E"} ;
Style[{#1," = ", #2 /. display // Simplify // TraditionalForm } &@@@{
{"<100|x|100>",braketSurface[ 1, x ] },
{"<100|y|100>",braketSurface[ 1, y ] },
{"<100|z|100>",braketSurface[ 1, z ] },
{"|2s>", psi2s[r,θ, ϕ] },
{"|2px>", psi2px[r,θ, ϕ] },
{"|2py>", psi2py[r,θ, ϕ] },
{"|2pz>", psi2pz[r,θ, ϕ] },
{"<2l'm'|e E z | 2 l m>", v // MatrixForm},
{"eigenvalues",(# /. display) &/@ (ei // First) // Column},
{"diag basis", (# // MatrixForm) &/@ (ei // Last) // Column}
} // Grid ,sopts]