Verify all the hand calculations for ps7 p2, Helium atom ground state without electron-electron interaction.

ClearAll[psi, r,a, hbar, m, eps, inner, psiSquared, expectationInverseRadial, h, e, hPsi, display, energy,bohrRadius, eSimplify, bohrRadiusValue]

(* declare various variables as Real and > 0 *)
$Assumptions=And@@(#>0&)/@{m, a, hbar, m, eps, e, k};

(* ψ(r) *)
psi := E^(-(#1 + #2)/a) & ;

(* patterns for pretty print formatting *)
display := {hbar -> ℏ,eps -> (Subscript[ϵ, 0])} ;

 (* <f|g>, for real eigenfunctions that have only radial dependence. *)
inner[f_, g_] := (4 Pi)^2 Integrate[ r2^2r1^2 f[r1,r2] g[r1,r2], {r1, 0, Infinity}, {r2, 0, Infinity}]

(* <ψ|ψ>, <ψ|(1/(Subscript[r, 1]))|ψ> *)
psiSquared = inner[ psi, psi ] ;
expectationInverseRadial = inner[ psi, psi[#1,#2]/#1&] ;

(* <(Subscript[r, 1])(Subscript[r, 2])|H|ψ> *)
hPsi := (-(hbar^2/2/m/a)(2/a - 2/#1 - 2/#2) - 2(e^2/4/Pi/eps)(1/#1 + 1/#2))psi[#1, #2] & ;

(* <ψ|H|ψ>/<ψ|ψ> *)
energy =(inner[ psi, hPsi ]/psiSquared // Simplify) ;

(* (Subscript[a, 0 ])*)
bohrRadiusValue = 4 Pi eps hbar^2/(m e^2)  ;
bohrRadius = { a ->  bohrRadiusValue} ;

(* Solve ∂E/∂a == 0 *)
s = Solve[0 == D[energy, {a,1}], {a}] // Flatten ;

(* E(Subscript[|, (Subscript[a, min])]) *)
eSimplify= energy /. s // Simplify ;


{#1," = ",#2/. display // TraditionalForm } &@@@{
{"<ψ|ψ>", psiSquared},
{"<ψ|(1/(Subscript[r, 1]))|ψ>", expectationInverseRadial},
{"<ψ|H|ψ>/<ψ|ψ>", energy},
{"(Subscript[a, min])",a /.s},
{"<ψ|H|ψ>/<ψ|ψ>\!\(\*SubscriptBox[\(|\), \(a\\  = \\ \*SubscriptBox[\(a\), \(min\)]\)]\)", eSimplify},
{"<ψ|H|ψ>/<ψ|ψ>|a = (Subscript[a, min])", eSimplify   bohrRadiusValue/(Subscript[a, 0]) /. display} (* display in terms of (Subscript[a, 0]) *)
} // Grid

ClearAll[ f1, interaction, interactionScaled, energyInteraction, s, minE, intk8 ]

(* ∫2 π dr dθ (r^2) sin(θ)exp(−r/a+ik·r ) *)
f1 = Integrate[ 2 Pi r^2 Sin[t] Exp[I k r Cos[t] - 2r/a], {t, 0, Pi}, {r, 0, Infinity}] ;

(* ((e^2)/(4 π (Subscript[ϵ, 0]))) <ψ|(1/(|(Subscript[r, 1])−(Subscript[r, 2])|))|ψ> *)
interaction = (e^2/4/Pi/eps) (1/2/Pi^2) (4 Pi) Integrate[  f1^2, {k, 0, Infinity}] ;

(* ((e^2)/(4 π (Subscript[ϵ, 0])))<ψ|(1/(|(Subscript[r, 1])−(Subscript[r, 2])|))|ψ>/<ψ|ψ> *)
interactionScaled = interaction/psiSquared ;

(* E = <ψ|H|ψ>/<ψ|ψ> *)
energyInteraction = interactionScaled+ energy // Simplify ;

(* Solve ∂E/∂a == 0 *)
s = Solve[0 == D[energyInteraction, {a,1}], {a}] // Flatten ;

minE = energyInteraction /. s // Simplify ;

intk8 = Integrate[  ( (1/((((a^2) (k^2)+1))^2)))^2 ,{k, 0, Infinity}] // HoldForm ;

{#1," = ",#2/. display // TraditionalForm } &@@@ {
{"∫2 π dr dθ (r^2) sin(θ)exp(−r/a+ik·r )", f1},
{intk8 // TraditionalForm, intk8 // ReleaseHold},
{"\!\(\*FractionBox[SuperscriptBox[\(e\), \(2\)], \(4\\ π\\ \*SubscriptBox[\(ϵ\), \(0\)]\)]\)<ψ|(1/(|(Subscript[r, 1]) − (Subscript[r, 2])|))|ψ>", interaction },
{"\!\(\*FractionBox[SuperscriptBox[\(e\), \(2\)], \(4\\ π\\ \*SubscriptBox[\(ϵ\), \(0\)]\)]\)<ψ|(1/(|(Subscript[r, 1]) − (Subscript[r, 2])|))|ψ>/<ψ|ψ>", interactionScaled },
{"<ψ|H|ψ>/<ψ|ψ>", energyInteraction },
{"∂E/∂a == 0 ; (Subscript[a, min])", a /. s },
{"(Subscript[E, min])", minE},
{"<ψ|H|ψ>/<ψ|ψ>|a = (Subscript[a, min])", minE   bohrRadiusValue/(Subscript[a, 0]) } (* display in terms of (Subscript[a, 0]) *)
} // Grid