Verify all the hand calculations for ps7 p2, Hydrogen atom ground state.

ClearAll[psi, r,a, hbar, m, eps, inner, psiSquared, expectationInverseRadial, h, e, hPsi, display, bohrRadius, eSimplify, s, eMin]

(* declare various variables as Real and > 0 *)
$Assumptions=And@@(#>0&)/@{m, a, hbar, m, eps, e};

(* ψ(r) *)
psi := E^(-#/a) & ;

(* patterns for pretty print formatting *)
display := {hbar -> ℏ,eps -> (Subscript[ϵ, 0])} ;

(* <f|g>, for real eigenfunctions that have only radial dependence. *)
inner[f_, g_] := 4 Pi Integrate[ r^2 f[r] g[r], {r, 0, Infinity}]

(* <ψ|ψ>, <ψ|(1/r)|ψ> *)
psiSquared = inner[ psi, psi ] ;
expectationInverseRadial = inner[ psi, psi[#]/# &] ;

(* <r|H|ψ> *)
hPsi := (-(hbar^2/2/m/a)(1/a - 2/#) - e^2/4/Pi/eps/#)E^(-#/a) & ;

(* <ψ|H|ψ>/<ψ|ψ> *)
energy =inner[ psi, hPsi ]/psiSquared // Simplify ;

bohrRadius = { a -> 4 Pi eps hbar^2/(m e^2) } ;

eSimplify = energy /. bohrRadius // Simplify ;

s = Solve[0 == D[energy, {a,1}], {a}] // Flatten ;

eMin = energy /. s // Simplify ;

{#1," = ",#2/. display // TraditionalForm } &@@@{
{"<ψ|ψ>", psiSquared},
{"<ψ|(1/r)|ψ>", expectationInverseRadial},
{"<ψ|H|ψ>/<ψ|ψ>", energy},
{"(Subscript[a, min])",a /.s},
{"<ψ|H|ψ>/<ψ|ψ>|a = (Subscript[a, min])", eMin},
{"<ψ|H|ψ>/<ψ|ψ>|a = (Subscript[a, 0])", eSimplify},
{"<ψ|H|ψ>/<ψ|ψ>|a = (Subscript[a, 0])", eMin   (4 Pi eps hbar^2/(m e^2))(4 Pi eps)/DisplayForm[RowBox[{"4" ,"π" ,"(Subscript[ϵ, 0])", "(Subscript[a, 0])"}]] /. display}

} // Grid

Numerical calculations

(*bohrRadiusSI=5.2919999999999997 10^(-11)  (*m*)*)
hbarSI = 1.0545 (10^(-34)) (* m^2 kg/s *)
massOfElectronSI = 9.10938 (10^(-31)) (* kg *)

eNoughtSI=8.85418 (10^(-12)) (* F/m *)
electricChargeSI =-1.60217  (10^(-19)) (* C *)
bohrRadiusSI = 4 Pi eNoughtSI hbarSI^2/massOfElectronSI/electricChargeSI^2 (* m *)
eVperJoule = 1/(1.60217  (10^(-19)))(* eV/J *)
eSquaredEnergyAtBohrRadius = eVperJoule electricChargeSI^2/(4 Pi eNoughtSI bohrRadiusSI) 
(*or: *)
(*eSquaredEnergyAtBohrRadius = electricChargeSI^3 massOfElectronSI/(4 Pi eNoughtSI hbarSI)^2*)

(* Hydrogen ground state in eV *)
-eSquaredEnergyAtBohrRadius/2
(* Helium variational ground state in eV *)
-(27/16)^2 eSquaredEnergyAtBohrRadius