Explicit 4x4 expansion of the Dirac matrices using the Weyl representation, and verification of some identities.

i2 = IdentityMatrix[2];
i4 = IdentityMatrix[4];
o2 = {{0,0},{0,0}};

gamma0 = {{o2, i2}, {i2, o2}} // ArrayFlatten;
sigma1 = PauliMatrix[1];
sigma2 = PauliMatrix[2];
sigma3 = PauliMatrix[3];


gamma1 = {{o2, sigma1}, {-sigma1, o2}} // ArrayFlatten;
gamma2 = {{o2, sigma2}, {-sigma2, o2}} // ArrayFlatten;
gamma3 = {{o2, sigma3}, {-sigma3, o2}} // ArrayFlatten;

gamma = {gamma0, gamma1, gamma2, gamma3};

Visual representation:

gamma0 // MatrixForm
gamma1//MatrixForm
gamma2//MatrixForm
gamma3//MatrixForm

Verify the metric sign convention:

{gamma0. gamma0 -i4// MatrixForm,
gamma1.gamma1+i4//MatrixForm,
gamma2.gamma2+i4//MatrixForm,
gamma3.gamma3+i4//MatrixForm} // Row

Verify that (SuperDagger[(γ^0)(i (γ^μ))])(γ^0) = -((iγ)^μ) :

{(gamma0 . ConjugateTranspose[I gamma0] . gamma0 + I gamma0) // MatrixForm,
(gamma0.ConjugateTranspose[I gamma1].gamma0+I gamma1)//MatrixForm,
(gamma0.ConjugateTranspose[I gamma2].gamma0+I gamma2)//MatrixForm,
(gamma0.ConjugateTranspose[I gamma3].gamma0+I gamma3)//MatrixForm} // Row

Verify: (SuperDagger[((γ^0))])= (γ^0), (SuperDagger[((γ^k))])= -(γ^k)

{(gamma0 // ConjugateTranspose )- gamma0,
(gamma1 // ConjugateTranspose) + gamma1,
(gamma2 // ConjugateTranspose) + gamma2,
(gamma3 // ConjugateTranspose) + gamma3} // Row

arg = gamma0 . ( om01 gamma1 + om02 gamma2 + om03 gamma3) + gamma1 . (om12 gamma2 + om13 gamma3 ) + gamma2 . gamma3 om23;
f := {om01 -> (Subscript[ω, 0,1]), om02 -> (Subscript[ω, 0,2]),om03 -> (Subscript[ω, 0,3]),
om12 -> (Subscript[ω, 1,2]), om13 -> (Subscript[ω, 1,3]),om23 -> (Subscript[ω, 2,3])};
(arg /. f) // MatrixForm
$Assumptions = om01 ∈ Reals && om02 ∈ Reals && om03 ∈ Reals && om12 ∈ Reals && om23 ∈ Reals && om13 ∈ Reals;
(*(Exp[arg] /. f)// MatrixForm*)